Subversion Repositories compaq-c-overlay

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/libcpml/libcpml-5.2.01.ebuild,v 1.5 2004/07/02 04:44:16 eradicator Exp $

inherit eutils rpm

DESCRIPTION="Compaq's Optimized Math Library for the Alpha Platform"
HOMEPAGE="ftp://ftp.compaq.com/pub/products/C-CXX/linux/"
SRC_URI="ev6? ( cpml_ev6-5.2.0-1.alpha.rpm )
        !ev6? ( cpml_ev5-5.2.0-1.alpha.rpm )"

LICENSE="compaq-sdla"
SLOT="5.2.01"
KEYWORDS="-* ~alpha"
IUSE="ev6"
RESTRICT="fetch strip mirror"

DEPEND="sys-devel/binutils
        sys-apps/findutils"
RDEPEND="dev-libs/libots"

S=${WORKDIR}/usr

src_unpack() {
        rpm_src_unpack
        find "${S}" -type d -exec chmod a+rx {} \;
}

src_compile () {
        local EV; use ev6 && EV=ev6 || EV=ev5
        cd "${S}"/lib/compaq/cpml-5.2.0
        ld -shared -o libcpml_${EV}.so -soname libcpml.so \
                -whole-archive libcpml_${EV}.a -no-whole-archive -lots
}

src_install() {
        local EV; use ev6 && EV=ev6 || EV=ev5

        mv "${S}" "${D}"

        dodir /usr/lib/
        dosym ./compaq/cpml-5.2.0/libcpml_${EV}.so /usr/lib/libcpml_${EV}.so
        dosym ./compaq/cpml-5.2.0/libcpml_${EV}.a /usr/lib/libcpml_${EV}.a

        dodir /usr/share
        mv "${D}"/usr/doc "${D}"/usr/share

        dosym ./compaq/cpml-5.2.0/libcpml_${EV}.so /usr/lib/libcpml.so
        dosym ./compaq/cpml-5.2.0/libcpml_${EV}.a /usr/lib/libcpml.a

        prepall
}